0 BEGIN PGM 10005_IT MM 
1 ;Pezzo da fresare-tornire
2 ;
3 ;Definizione del pezzo grezzo come cilindro
4 BLK FORM CYLINDER Z R60 L100 DIST+1
5 ;
6 ;Attivazione dell'origine
7 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
   Q339=+2    ;BEZUGSPUNKT-NUMMER
8 ;
9 ;Tornitura di sgrossatura esterna
10 ;Chiamata utensile per tornire sgrossatura
11 TOOL CALL "TURN_ROUGH"
12 ;
13 ;Chiamata sottoprogramma Modalità di tornitura
14 CALL LBL "TURN"
15 ;Chiamata sottoprogramma Raggiungimento della posizione di sicurezza
16 CALL LBL "SAFE"
17 ;
18 ;Adattamento del sistema di tornitura
19 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
   Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
20 ;
21 ;Velocità di taglio costante e definizione
22 ;del numero di giri massimo
23 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
24 ;
25 ;Azzeramento dell'asse orientabile e
26 ;attivazione del mandrino rotativo
27 L  A+0 R0 FMAX M303
28 ;
29 ;Tornitura a sfacciare
30 CYCL DEF 821 ABSATZ PLAN ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+0    ;KONTURENDE DURCHMESSER ~
    Q494=+0    ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0    ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
31 L  X+122  Y+0 R0 FMAX ;Preposizionamento
32 L  Z+10 R0 FMAX ;Preposizionamento
33 L  Z+2 R0 F0.5 M99 ;Raggiungimento dell'altezza di partenza e chiamata ciclo
34 ;
35 ;Tornitura in tondo
36 CYCL DEF 811 ABSATZ LAENGS ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+117  ;KONTURENDE DURCHMESSER ~
    Q494=-80   ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.2  ;AUFMASS DURCHMESSER ~
    Q484=+0    ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
37 L  X+122  Y+0 R0 FMAX ;Preposizionamento
38 L  Z+10 R0 FMAX ;Preposizionamento
39 L  Z+2 R0 F0.5 M99 ;Raggiungimento dell'altezza di partenza e chiamata ciclo
40 ;
41 ;Tornitura gradino
42 CYCL DEF 811 ABSATZ LAENGS ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+100  ;KONTURENDE DURCHMESSER ~
    Q494=-20   ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.2  ;AUFMASS DURCHMESSER ~
    Q484=+0    ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
43 L  X+119  Y+0 R0 FMAX ;Preposizionamento
44 L  Z+10 R0 FMAX ;Preposizionamento
45 L  Z+2 R0 F0.5 M99 ;Raggiungimento dell'altezza di partenza e chiamata ciclo
46 ;
47 ;Chiamata utensile per troncatura-tornitura assiale
48 TOOL CALL "TURN_REC_AX_100-150"
49 ;
50 ;Chiamata sottoprogramma Modalità di tornitura
51 CALL LBL "TURN"
52 ;Chiamata sottoprogramma Raggiungimento della posizione di sicurezza
53 CALL LBL "SAFE"
54 ;
55 ;Adattamento del sistema di tornitura
56 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
   Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
57 ;
58 ;Velocità di taglio costante e definizione del
59 ;numero di giri massimo
60 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
61 ;
62 ;Azzeramento dell'asse orientabile e
63 ;attivazione del mandrino rotativo
64 L  A+0 R0 FMAX M303
65 ;
66 ;Gola assiale
67 CYCL DEF 852 STECHDR. ERW. AXIAL ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+85   ;KONTURSTART DURCHMESSER ~
    Q492=+0    ;KONTURSTART Z ~
    Q493=+50   ;KONTURENDE DURCHMESSER ~
    Q494=-5    ;KONTURENDE Z ~
    Q495=+0    ;WINKEL FLANKE ~
    Q501=+1    ;TYP ANFANGSELEMENT ~
    Q502=+0.5  ;GROESSE ANFANGSELEMENT ~
    Q500=+0.5  ;RADIUS KONTURECKE ~
    Q496=+0    ;WINKEL ZWEITE FLANKE ~
    Q503=+1    ;TYP ENDELEMENT ~
    Q504=+0.5  ;GROESSE ENDELEMENT ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR
68 L  X+85  Y+0 R0 FMAX ;Preposizionamento
69 L  Z+10 R0 FMAX ;Preposizionamento
70 L  Z+2 R0 F0.5 M99 ;Raggiungimento dell'altezza di partenza e chiamata ciclo
71 ;
72 ;Tornitura Gola radiale
73 ;Chiamata utensile per troncatura-tornitura radiale
74 TOOL CALL "TURN_REC_RAD"
75 ;
76 ;Tornitura Gola radiale
77 CALL LBL "TURN"
78 ;Chiamata sottoprogramma Raggiungimento della posizione di sicurezza
79 CALL LBL "SAFE"
80 ;
81 ;Adattamento del sistema di tornitura
82 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
   Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
83 ;
84 ;Velocità di taglio costante e definizione del
85 ;numero di giri massimo
86 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
87 ;
88 ;Azzeramento dell'asse orientabile e attivazione
89 ;del mandrino rotativo
90 L  A+0 R0 FMAX M303
91 ;
92 ;Tornitura profilo
93 CYCL DEF 14.0 KONTUR
94 CYCL DEF 14.1 KONTURLABEL1
95 CYCL DEF 840 STECHDR. KONT. RAD. ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q488=+0.1  ;VORSCHUB EINTAUCHEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR ~
    Q499=+0    ;KONTUR UMKEHREN
96 L  X+119  Y+0 R0 FMAX ;Preposizionamento
97 L  Z+10 R0 FMAX ;Preposizionamento
98 L  Z+2 R0 F0.5 M99 ;Raggiungimento dell'altezza di partenza e chiamata ciclo
99 ;
100 ;Gola radiale
101 CYCL DEF 841 STECHDR. EINFACH R. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+105  ;KONTURENDE DURCHMESSER ~
    Q494=-40   ;KONTURENDE Z ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR
102 L  X+119  Y+0 R0 FMAX ;Preposizionamento
103 L  Z+10 R0 FMAX ;Preposizionamento
104 L  Z-23 R0 F0.5 M99 ;Raggiungimento dell'altezza di partenza e chiamata ciclo
105 ;
106 ;Lavorazione di fresatura foro
107 ;Chiamata sottoprogramma Modalità di fresatura
108 CALL LBL "MILL"
109 ;
110 ;Chiamata utensile fresa a candela
111 TOOL CALL "MILL_D20_ROUGH" Z S3000 F700
112 ;
113 L  X+0  Y+0  Z+100 R0 FMAX M3 ;Preposizionamento
114 ;
115 ;Fresatura foro
116 CYCL DEF 208 BOHRFRAESEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-60   ;TIEFE ~
    Q206=+500  ;VORSCHUB TIEFENZ. ~
    Q334=+2.5  ;ZUSTELL-TIEFE ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q335=+32   ;SOLL-DURCHMESSER ~
    Q342=+0    ;VORGEB. DURCHMESSER ~
    Q351=+1    ;FRAESART
117 M99 ;Chiamata ciclo
118 ;
119 ;Chiamata sottoprogramma Raggiungimento della posizione di sicurezza
120 CALL LBL "SAFE"
121 ;
122 ;Tornitura di sgrossatura interna
123 ;Chiamata utensile per tornire sgrossatura
124 TOOL CALL "TURN_ROUGH"
125 ;
126 ;Chiamata sottoprogramma Modalità di tornitura
127 CALL LBL "TURN"
128 ;Chiamata sottoprogramma Raggiungimento della posizione di sicurezza
129 CALL LBL "SAFE"
130 ;
131 ;Adattamento del sistema di tornitura
132 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+1    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
133 ;
134 ;Velocità di taglio costante e definizione
135 ;del numero di giri massimo
136 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
137 ;
138 ;Azzeramento dell'asse orientabile e attivazione
139 ;del mandrino rotativo (M304 inversione utensile)
140 L  A+0 R0 FMAX M304
141 ;
142 ;Tornitura interna imbocco
143 CYCL DEF 821 ABSATZ PLAN ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+84   ;KONTURENDE DURCHMESSER ~
    Q494=-5    ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
144 L  X+30  Y+0 R0 FMAX ;Preposizionamento
145 L  Z+2 R0 FMAX M99 ;Raggiungimento della posizione di partenza e chiamata ciclo
146 ;
147 ;Tornitura interna gradino
148 CYCL DEF 822 ABSATZ PLAN ERW. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+32   ;KONTURSTART DURCHMESSER ~
    Q492=-5    ;KONTURSTART Z ~
    Q493=+75   ;KONTURENDE DURCHMESSER ~
    Q494=-40   ;KONTURENDE Z ~
    Q495=+0    ;WINKEL PLANFLAECHE ~
    Q501=+0    ;TYP ANFANGSELEMENT ~
    Q502=+1    ;GROESSE ANFANGSELEMENT ~
    Q500=+1    ;RADIUS KONTURECKE ~
    Q496=+0    ;WINKEL UMFANGSFLAECHE ~
    Q503=+2    ;TYP ENDELEMENT ~
    Q504=+1    ;GROESSE ENDELEMENT ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
149 L  X+30  Y+0 R0 FMAX ;Preposizionamento
150 L  Z-3 R0 FMAX M99 ;Raggiungimento della posizione di partenza e chiamata ciclo
151 L  Z+10 R0 FMAX ;Disimpegno
152 ;
153 ;Chiamata sottoprogramma Raggiungimento della posizione di sicurezza
154 CALL LBL "SAFE"
155 ;
156 ;Tornitura di finitura esterna
157 ;Chiamata utensile per tornire finitura
158 TOOL CALL "TURN_FINISH"
159 ;
160 ;Chiamata sottoprogramma Modalità di tornitura
161 CALL LBL "TURN"
162 ;
163 ;Attivazione del ricalcolo del grezzo
164 ;Pezzo grezzo definito nel sottoprogramma Blank
165 FUNCTION TURNDATA BLANK LBL "Blank"
166 ;
167 ;Adattamento del sistema di tornitura
168 ;Utensile inclinato per realizzazione gola
169 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+90   ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+2    ;ANGESTELLTE BEARB. ~
    Q531=+30   ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=-1    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
170 ;
171 ;Velocità di taglio costante e definizione
172 ;del numero di giri massimo
173 FUNCTION TURNDATA SPIN VCONST:ON VC:500 S800
174 ;
175 M303
176 ;Finitura profilo
177 CYCL DEF 14.0 KONTUR
178 CYCL DEF 14.1 KONTURLABEL3
179 CYCL DEF 810 DREHEN KONTUR LAENGS ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q499=+0    ;KONTUR UMKEHREN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.1  ;AUFMASS DURCHMESSER ~
    Q484=+0.1  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q487=+1    ;EINTAUCHEN ~
    Q488=+0    ;VORSCHUB EINTAUCHEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q506=+0    ;KONTURGLAETTUNG
180 M99 ;Chiamata ciclo
181 ;
182 ;Tornitura filetto
183 ;Chiamata utensile per tornitura filetto
184 TOOL CALL "TURN_THREAD"
185 ;
186 ;Chiamata sottoprogramma Modalità di tornitura
187 CALL LBL "TURN"
188 ;
189 ;Chiamata sottoprogramma Raggiungimento della posizione di sicurezza
190 CALL LBL "SAFE"
191 ;
192 ;Adattamento del sistema di tornitura
193 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
194 ;
195 ;Velocità di taglio costante e definizione
196 ;del numero di giri massimo
197 FUNCTION TURNDATA SPIN VCONST:ON VC:300 SMAX800
198 ;
199 ;Azzeramento dell'asse orientabile e attivazione
200 ;del mandrino rotativo
201 L  A+0 R0 FMAX M304
202 ;
203 ;Tornitura filetto
204 CYCL DEF 831 GEWINDE LAENGS ~
    Q471=+0    ;GEWINDELAGE ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+95   ;GEWINDEDURCHMESSER ~
    Q472=+1.5  ;GEWINDESTEIGUNG ~
    Q473=+0    ;GEWINDETIEFE ~
    Q492=+0    ;KONTURSTART Z ~
    Q494=-20   ;KONTURENDE Z ~
    Q474=+0    ;GEWINDEAUSLAUF ~
    Q463=+0.3  ;MAX. SCHNITTTIEFE ~
    Q467=+0    ;ZUSTELLWINKEL ~
    Q468=+1    ;ZUSTELLART ~
    Q470=+0    ;STARTWINKEL ~
    Q475=+1    ;GANGANZAHL ~
    Q476=+2    ;ANZAHL LEERSCHNITTE
205 L  X+98  Y+0 R0 FMAX ;Preposizionamento
206 L  Z+2 R0 FMAX ;Raggiungimento posizione di partenza
207 M99 ;Chiamata ciclo
208 ;
209 ;Tornitura Gola radiale
210 ;Chiamata utensile per troncatura-tornitura radiale
211 TOOL CALL "TURN_REC_RAD"
212 ;
213 ;Chiamata sottoprogramma Modalità di tornitura
214 CALL LBL "TURN"
215 ;Chiamata sottoprogramma Raggiungimento della posizione di sicurezza
216 CALL LBL "SAFE"
217 ;
218 ;Adattamento del sistema di tornitura
219 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
220 ;
221 ;Velocità di taglio costante e definizione
222 ;del numero di giri massimo
223 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
224 ;
225 ;Azzeramento dell'asse orientabile e attivazione
226 ;del mandrino rotativo
227 L  A+0 R0 FMAX M303
228 ;
229 ;Tornitura Gola radiale
230 ;Tornitura profilo
231 CYCL DEF 14.0 KONTUR
232 CYCL DEF 14.1 KONTURLABEL4
233 CYCL DEF 840 STECHDR. KONT. RAD. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q488=+0.1  ;VORSCHUB EINTAUCHEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR ~
    Q499=+0    ;KONTUR UMKEHREN
234 L  X+119  Y+0 R0 FMAX ;Preposizionamento
235 L  Z+10 R0 FMAX ;Preposizionamento
236 L  Z+2 R0 F0.5 M99 ;Raggiungimento della posizione di partenza e chiamata ciclo
237 ;
238 ;Chiamata sottoprogramma Modalità di fresatura
239 CALL LBL "MILL"
240 ;Chiamata sottoprogramma Raggiungimento della posizione di sicurezza
241 CALL LBL "SAFE"
242 ;Fine programma
243 M30
244 ;
245 ;Sottoprogramma Modalità di tornitura
246 LBL "TURN"
247 M140 MB MAX ;Disimpegno
248 M145 ;Annullamento calcolo cinematica
249 FUNCTION MODE TURN ;Attivazione Modalità di tornitura
250 M144 ;Attivazione calcolo cinematica
251 M136 ;Commutazione avanzamento su mm al giro
252 LBL 0
253 ;
254 ;Sottoprogramma Modalità di fresatura
255 LBL "MILL"
256 M140 MB MAX ;Disimpegno
257 M145 ;Annullamento calcolo cinematica
258 FUNCTION MODE MILL ;Attivazione Modalità di fresatura
259 M137 ;Commutazione avanzamento su mm al minuto
260 ;Chiamata sottoprogramma Raggiungimento della posizione di sicurezza
261 CALL LBL "SAFE"
262 L  C+0  A+0 R0 FMAX ;Azzeramento degli assi orientabili
263 LBL 0
264 ;
265 ;Sottoprogramma Raggiungimento della posizione di sicurezza
266 LBL "SAFE"
267 L  X+400  Y+400 R0 FMAX M91 ;Posizione di sicurezza !A seconda della macchina!
268 LBL 0
269 ;
270 ;Profilo per ricalcolo del grezzo
271 LBL "Blank"
272 L  Z+0  X+0
273 L  Z+0  X+100
274 L  Z-20  X+100
275 L  Z-20  X+116.9997
276 L  Z-23  X+117
277 L  Z-23  X+105
278 L  Z-40  X+105
279 L  Z-40  X+116.9997
280 L  Z-43  X+117
281 L  Z-43  X+100
282 L  Z-56.9063  X+100
283 L  Z-56.9063  X+0
284 L  Z-60  X+117
285 L  Z-60  X+0
286 L  Z-80  X+117
287 L  Z-80  X+119.9997
288 L  Z-100  X+120
289 L  Z-100  X+0
290 L  Z+0
291 LBL 0
292 ;
293 ;Profilo1
294 LBL 1
295 L  X+117  Z-43 RL
296 L  X+100
297 L  Z-56.9063
298 L  X+117  Z-60
299 LBL 0
300 ;
301 ;Profilo3
302 LBL 3
303 L  X+90  Z+0
304 L  X+95
305 RND R2
306 L  Z-20
307 UDC THREAD PITCH1.5 R0.8 DEPTH0.8 BREADTH5 ;Scarico
308 L  X+110
309 LBL 0
310 ;
311 ;Profilo4
312 LBL 4
313 L  X+105  Z-23
314 L  Z-27
315 GRV RADIAL CENTER-31.5 R1 DIAM89 BREADTH9 ANG_WIDTH28.072 RND1 FAR_RND1 ;Scarico
316 L  Z-40
317 LBL 0
318 END PGM 10005_IT MM