0 BEGIN PGM 1065_IT MM 
1 ;Programma per eseguire la centrinatura
2 ;su diverse posizioni, per creare un
3 ;foro pilota e per forare quindi a
4 ;maggiore profondità.
5 ;Le posizioni e altri parametri di
6 ;foratura sono salvati in una tabella.
7 ;
8 BLK FORM 0.1 Z X+0 Y+0 Z-100
9 BLK FORM 0.2  X+100  Y+100  Z+0
10 ;
11 ;Definizione della tabella con parametri di
12 ;foratura
13 FN 26: TABOPEN 10651_it.tab
14 ;
15 ;Chiamata utensile punta per centrinatura
16 TOOL CALL 203 Z S2000
17 ;
18 CYCL DEF 203 FORATURA UNIVERS ~
   Q200=+2    ;DISTANZA SICUREZZA ~
    Q201=-3    ;PROFONDITA ~
    Q206=+150  ;AVANZ. INCREMENTO ~
    Q202=+5    ;PROF. INCREMENTO ~
    Q210=+0    ;TEMPO ATTESA SOPRA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA ~
    Q212=+0    ;VALORE DA TOGLIERE ~
    Q213=+0    ;N. ROTTURA TRUCIOLI ~
    Q205=+0    ;MIN. PROF INCREMENTO ~
    Q211=+0    ;TEMPO ATTESA SOTTO ~
    Q208=+30000 ;AVANZAM. RITORNO ~
    Q256=+0.2  ;RITIRO ROTT.TRUCIOLO
19 ;
20 ;Definizione delle righe da impiegare della tabella
21 FN 0: Q51 =+0 ;RIGA DI PARTENZA
22 FN 0: Q52 =+4 ;ALTRE RIGHE
23 ;
24 CALL LBL 12
25 ;
26 STOP
27 ;
28 ;Chiamata utensile punta per foro pilota
29 TOOL CALL 227 Z S2000
30 ;
31 ;Definizione dei parametri da modificare del ciclo di foratura
32 FN 0: Q201 =-10 ;Nuova profondità
33 ;
34 CALL LBL 12
35 ;
36 STOP
37 ;
38 ;Chiamata utensile per la foratura profonda
39 TOOL CALL 226 Z
40 ;
41 ;Definizione dei parametri per la foratura profonda
42 FN 0: Q1 =+0 ;Bordo superiore
43 FN 0: Q2 =+0 ;Profondità di preforatura
44 FN 0: Q3 =-10 ;Altezza di trasporto trucioli
45 FN 0: Q4 =+1000 ;Avanzamento per penetrazione
46 FN 0: Q5 =+200 ;Avanzamento per foratura
47 FN 0: Q6 =+2000 ;N. giri
48 FN 0: Q7 =+5 ;Incremento
49 FN 0: Q8 =+0 ;Profondità
50 FN 0: Q9 =+0.5 ;Tempo di sosta
51 FN 0: Q10 =+1 ;Valore rottura truciolo
52 FN 0: Q11 =+2 ;Valore di sicurezza 1 (incrementale)
53 FN 0: Q12 =+30 ;Valore di sicurezza 2 (incrementale)
54 FN 0: Q13 =+5 ;Numero degli avanzamenti
55 ;
56 ;Definizione di PGM 10652_it.h come ciclo
57 CYCL DEF 12.0 PGM CALL
58 CYCL DEF 12.1 PGM 10652_it.h
59 ;
60 CALL LBL 12
61 ;
62 ;Disimpegno e fine programma
63 L  X+0  Y+0  Z+100 FMAX M2
64 ;
65 ;Raggiungimento posizioni
66 LBL 12
Q61 = Q51 ;Definizione della riga della tabella della prima posizione
67 LBL 11
68 CALL LBL 10
69 FN 1: Q61 =+Q61 + +1 ;Ulteriore calcolo della riga della tabella
70 CALL LBL 11 REPQ52
71 LBL 0
72 ;
73 ;Comandi di lettura, raggiungimento della posizione e chiamata ciclo
74 LBL 10
75 FN 28: TABREAD Q41 =Q61 /"X"
76 FN 28: TABREAD Q42 =Q61 /"Y"
77 FN 28: TABREAD Q1 =Q61 /"Z"
78 FN 28: TABREAD Q8 =Q61 /"Depth"
79 FN 28: TABREAD Q45 =Q61 /"Distance"
80 FN 28: TABREAD Q46 =Q61 /"Feed_rate"
81 FN 28: TABREAD Q47 =Q61 /"Safe_height"
82 L  X+Q41  Y+Q42 R0 FMAX M13 M99
83 LBL 0
84 END PGM 1065_IT MM