0 BEGIN PGM 2145_IT MM 
1 ;Programma NC in cui è definito un ciclo SL. La
2 ;particolarità è che con un parametro Q è
3 ;possibile selezionare il numero del
4 ;sottoprogramma da impiegare come profilo. A
5 ;tale scopo si definisce a inizio programma un
6 ;parametro con il numero del sottoprogramma da
7 ;impiegare, nell'esempio 11 o 12. Nel ciclo 14
8 ;è quindi indicato il numero del sottoprogramma
9 ;dell'isola e quello di un altro sottoprogramma.
10 ;Questo secondo sottoprogramma si compone
11 ;esclusivamente di un CALL LBL con il
12 ;parametro Q definito all'inizio affinché venga
13 ;impiegato il programma selezionato.
14 ;
15 BLK FORM 0.1 Z X+200 Y-50 Z-10
16 BLK FORM 0.2  X+300  Y+50  Z+30
17 ;
18 ;Chiamata utensile
19 TOOL CALL 4 Z S8000
20 ;
21 L  Z+100 R0 F9999 M3 ;Disimpegno
22 ;
23 FN 0: Q30 =+12 ;SELEZIONE DEL PROFILO DELLA TASCA
24 ;
25 ;Definizione del label del profilo
26 CYCL DEF 14.0 PROFILO
27 CYCL DEF 14.1 LABEL PROFILO10 /2
28 ;
29 ;Cicli di lavorazione
30 CYCL DEF 20 DATI DEL PROFILO ~
   Q1=-34   ;PROFONDITA'FRESATURA ~
    Q2=+1    ;SOVRAPP.TRAIET.UT. ~
    Q3=+0    ;QUOTA LATERALE CONS. ~
    Q4=+0    ;PROFONDITA' CONSEN. ~
    Q5=+30   ;COORD. SUPERFICIE ~
    Q6=+2    ;DISTANZA SICUREZZA ~
    Q7=+5    ;ALTEZZA DI SICUREZZA ~
    Q8=+0    ;RAGGIO DELLO SMUSSO ~
    Q9=+1    ;SENSO DI ROTAZIONE
31 CYCL DEF 22 SVUOTAMENTO ~
   Q10=-4    ;PROF. INCREMENTO ~
    Q11=+300  ;AVANZ. INCREMENTO ~
    Q12=+1500 ;AVANZ. PER SVUOT. ~
    Q18=+0    ;UTENSILE SGROSSATURA ~
    Q19=+500  ;AVANZAMENTO PENDOL. ~
    Q208=+99999 ;AVANZAM. RITORNO ~
    Q401=+70   ;FATTORE AVANZAMENTO ~
    Q404=+0    ;STRATEGIA FINITURA
32 CYCL CALL M3
33 L  Z+100 R0 F99999 ;Disimpegno
34 M30 ;Fine programma
35 ;
36 ;Sottoprogrammi
37 ;
38 LBL 2 ;Profilo isola
39 L  X+200  Y+26 RL
40 L  X+300  Y+36
41 L  Y-36
42 L  X+200  Y-26
43 L  X+200  Y+26
44 LBL 0
45 ;
46 LBL 10 ;Sottoprogramma selezione tasca
47 CALL LBL Q30
48 LBL 0
49 ;
50 LBL 11 ;Profilo tasca 1
51 L  X+194  Y-56 RR
52 L  Y+46
53 L  X+306
54 L  Y-46
55 L  X+194
56 LBL 0
57 ;
58 LBL 12 ;Profilo tasca 2
59 L  X+194  Y-56 RR
60 L  Y+56
61 L  X+306
62 L  Y-56
63 L  X+194
64 LBL 0
65 END PGM 2145_IT MM