0  BEGIN PGM 4040_IT MM 
1  BLK FORM 0.1 Z X-100 Y-100 Z-100
2  BLK FORM 0.2  X+100  Y+100  Z+0
3  ;Fresatura isola circolare
4  ;Chiamata utensile
5  TOOL CALL 10 Z S3000 F800
6  L  X+0  Y+0  Z+100 R0 FMAX M3
7  CYCL DEF 257 ISOLA CIRCOLARE ~
    Q223=+200  ;DIAMETRO PRECISO ~
    Q222=+283  ;DIAMETRO GREZZO ~
    Q368=+0    ;QUOTA LATERALE CONS. ~
    Q207= AUTO ;AVANZAM. FRESATURA ~
    Q351=+1    ;MODO FRESATURA ~
    Q201=-80   ;PROFONDITA ~
    Q202=+5    ;PROF. INCREMENTO ~
    Q206= AUTO ;AVANZ. INCREMENTO ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA ~
    Q370=+1    ;SOVRAPP.TRAIET.UT.
8  M99
9  L  Z+100 R0 FMAX M5
10 ;Fresatura scanalature su superficie cilindrica
11 ;Chiamata utensile
12 TOOL CALL 2 Z S5000 F500
13 ;Raggiungimento della posizione di sicurezza per
14 ;ruotare l'asse A
15 L  X+0  Y+0 R0 FMAX M3
16 M140 MB MAX F5000
17 ;Rotazione asse A
18 PLANE AXIAL  A-90 TURN FMAX
19 CALL LBL "Machining"
20 LBL "Takt"
21 ;Movimento incrementale dell'asse C
22 PLANE AXIAL IC+10 TURN FMAX
23 CALL LBL "Machining"
24 ;Ripetizione del ciclo
25 CALL LBL "Takt" REP34
26 M140 MB MAX F5000
27 PLANE RESET TURN FMAX
28 M30 ;Fine programma
29 ;Sottoprogramma
30 LBL "Machining"
31 ;Ciclo di lavorazione
32 ;Importante: coordinata superficie = raggio del cilindro!!!
33 CYCL DEF 253 FRES. SCANAL. ~
    Q215=+0    ;TIPO LAVORAZIONE ~
    Q218=+20   ;LUNGH. SCANALATURA ~
    Q219=+5    ;LARG. SCANALATURA ~
    Q368=+0    ;QUOTA LATERALE CONS. ~
    Q374=+100  ;ANGOLO DI ROTAZIONE ~
    Q367=+0    ;POSIZ. SCANALATURA ~
    Q207=+500  ;AVANZAM. FRESATURA ~
    Q351=+1    ;MODO FRESATURA ~
    Q201=-5    ;PROFONDITA ~
    Q202=+5    ;PROF. INCREMENTO ~
    Q369=+0    ;PROFONDITA' CONSEN. ~
    Q206=+150  ;AVANZ. INCREMENTO ~
    Q338=+0    ;INCREMENTO FINITURA ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q203=+100  ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA ~
    Q366=+0    ;PENETRAZIONE ~
    Q385=+500  ;AVANZAMENTO FINITURA
34 ;Posizione con chiamata ciclo
35 L  X+0  Y+25 R0 FMAX M99
36 LBL 0
37 END PGM 4040_IT MM