0 BEGIN PGM 42301_IT MM 
1 ;Programma NC per il calcolo e la lavorazione della coclea
2 ;di alimentazione.
3 ;Nel blocco di programma "SUBLOOP" è inoltre programmato
4 ;il profilo nel piano X/Y. Si tratta in tal caso di un profilo
5 ;che si compone di tre sezioni identiche e dopo averla
6 ;programmata una volta, la si ripete due volte ruotata
7 ;di 120 gradi.
8 ;Per poter realizzare i sottosquadri sul pezzo, è necessario
9 ;inclinare l'utensile.
10 ;A tale scopo si utilizza la funzione TCPM, mentre il sistema
11 ;di coordinate rimane invariato. Ma per la traslazione degli
12 ;assi rotativi il controllo il controllo numerico considera la
13 ;cinematica e posiziona il Tool Center Point, in questo caso il
14 ;centro della fresa sferica, sulla traiettoria programmata.
15 ;I movimenti di compensazione dell'asse C programmati in
16 ;questo programma per le traiettorie circolari del profilo sono
17 ;scelti in modo tale da non danneggiare il profilo.
18 ;
19 ;Inizio programma
Q10 = Q9 ;Profondità corrente
Q12 = Q2 / Q1 ;Rotazione al mm di profondità
Q20 = 5 + Q108 + Q7 ;Primo raggio incluso raggio utensile e sovrametallo
Q30 = Q6 - ( ( Q6 - ( 25 + Q20 ) ) / 2 ) ;Centro del cerchio per un avvicinamento dolce
20 PLANE RESET STAY ;Reset orientamento
21 L  Z+Q5 R0 FMAX M3 ;Raggiungimento dell'altezza di sicurezza
22 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL AXIS ;Attivazione della funzione TCPM
23 CC  X+0  Y+0 ;Centro del cerchio per il preposizionamento
24 LP  PR+Q6  PA+0 R0 FMAX ;Preposizionamento
25 L  B+Q4  A+0  C+0 R0 FMAX ;Avvicinamento all'angolo di inclinazione dell'asse B
26 ;
27 ;Label di salto per ripetizione
28 LBL "MAINLOOP"
Q11 = Q10 * Q12 ;Calcolo della rotazione attuale
29 ;
30 ;Rotazione del sistema di coordinate
31 CYCL DEF 10.0 DREHUNG
32 CYCL DEF 10.1  ROT+Q11
33 ;
34 L  C+Q11 R0 FMAX ;Movimento di compensazione dell'asse C
35 L  Z+Q10 R0 FMAX ;Avvicinamento alla nuova coordinata Z
36 CC  X+0  Y+0 ;Centro per preposizionamento
37 LP  PR+Q6  PA+0 R0 FMAX ;Preposizionamento su raggio di sicurezza
38 CC  X+Q30  Y+0 ;Centro del cerchio per il movimento di avvicinamento
39 CP  PA+180 DR- F AUTO ;Movimento di avvicinamento
40 CC  X+25  Y+0 ;Centro del cerchio raggio 5
41 ;
42 ;Ripetizione di blocchi di programma
43 ;in cui è scritto il profilo
44 LBL "SUBLOOP"
45 CP  PA+123.5 IC+33.5 DR+
46 CC  X+15.82  Y+13.86
47 CP IPA-102.6 IC+29.3 DR-
48 CC  X-23.05  Y-1.02
49 CP IPA+44.1 IC+48.8 DR+
50 CYCL DEF 10.0 DREHUNG
51 CYCL DEF 10.1 IROT+120
52 CC  X+25  Y+0
53 CP  PA+0 IC+8.4 DR+
54 CALL LBL "SUBLOOP" REP2
55 ;
56 CC  X+Q30  Y+0 ;Centro del cerchio per il movimento di allontanamento
57 CP  PA+0 DR- F AUTO ;Raggiungimento della posizione di sicurezza
58 L  Z+Q5 R0 FMAX ;Posizionamento ad altezza di sicurezza
59 LBL 0
60 ;
Q10 = Q10 + Q3 ;Calcolo della nuova coordinata Z
61 FN 11: IF +Q10 GT +Q1 GOTO LBL "MAINLOOP" ;Confronto se raggiunta profondità ed eventualmente salto
62 FN 0: Q10 =+Q1 ;Coordinata Y uguale a profondità
63 ;Salto alla fresatura profilo
64 CALL LBL "MAINLOOP"
65 L  B+0  C+0  A+0 R0 FMAX M5 ;Riposizionamento di tutti gli assi rotativi
66 FUNCTION RESET TCPM ;Reset della funzione TCPM
67 ;Fine programma
68 END PGM 42301_IT MM