0 BEGIN PGM 5025_IT MM 
1 ;Programma per sbavare un foro realizzato
2 ;nell'angolo destro rispetto all'asse del cilindro,
3 ;sulla superficie cilindrica, con una fresa a
4 ;sagomare.
5 ;La lavorazione viene eseguita nei tre assi lineari
6 ;senza orientare il piano di lavoro.
7 ;Come primo passo devono essere definiti tutti i
8 ;necessari parametri. In questo programma viene
9 ;quindi eseguito un blocco di programma di chiamata
10 ;utensile, posizionamento e ciclo di lavorazione per
11 ;creare il foro.
12 ;Anche in questo blocco di programma è necessario
13 ;definire tutti i parametri in quanto i parametri
14 ;precedentemente descritti sono effettivi solo per
15 ;la sbavatura.
16 ;Dopo aver lavorato il foro si definisce l'utensile
17 ;con cui deve essere eseguita la sbavatura. In
18 ;seguito il controllo numerico calcola le
19 ;coordinate per i singoli assi e le raggiunge.
20 ;Il controllo numerico calcola quindi il punto
21 ;successivo con la relativa coordinata X, Y e Z e
22 ;lo raggiunge. Questa sequenza viene ripetuta
23 ;fino a raggiungere di nuovo il punto di partenza.
24 ;In quanti punti la lavorazione viene suddivisa
25 ;si definisce con il parametro DIVISIONE.
26 ;!Importante! Il controllo numerico calcola il
27 ;movimento traiettoria per il centro dell'utensile.
28 ;Con il parametro OFFSET CENTRO UTENSILE DA
29 ;RAGGIO (Q7) si definisce in che misura il centro
30 ;dell'utensile è stato allontanato dal bordo del
31 ;foro. Durante tale operazione è necessario
32 ;considerare il segno: con segno positivo la
33 ;traiettoria del centro è maggiore del raggio, con
34 ;segno negativo minore.
35 ;
36 ;Immissione parametri
37 FN 0: Q3 =+100 ;RAGGIO CILINDRO
38 FN 0: Q4 =+100 ;DIVISIONE
39 FN 0: Q5 =+3 ;INDICARE PROFONDITA' POSITIVA
40 FN 0: Q1 =+0 ;CENTRO FORO IN X
41 FN 0: Q6 =+60 ;RAGGIO FORO
42 FN 0: Q7 =-0.5 ;OFFSET CENTRO UTENSILE DA RAGGIO
43 FN 0: Q10 =+20 ;DISTANZA DI SICUREZZA
44 FN 0: Q11 =+1000 ;AVANZAMENTO IN PROFONDITA'
45 FN 0: Q12 =+2000 ;AVANZAMENTO FRESATURA
46 ;Fine immissione parametri
47 ;
48 BLK FORM CYLINDER X RQ3 L200 DIST+100
49 ;
50 ;Spostamento origine sul centro del foro e
51 ;superficie del cilindro
52 CYCL DEF 7.0 NULLPUNKT
53 CYCL DEF 7.1  X+Q1
54 CYCL DEF 7.2  Z+Q3
55 ;
56 ;Chiamata utensile per il foro
57 TOOL CALL 8 Z S3000 F800
58 ;
59 L  Z+100 R0 FMAX M3 ;Posizionamento ad altezza di sicurezza
60 L  X+0  Y+0 R0 FMAX ;Raggiungimento del centro del foro
61 L  Z+Q10 R0 FMAX ;Posizionamento alla distanza di sicurezza
62 FN 3: Q80 =+Q6 * +2 ;Calcolo del diametro del foro
63 ;Ciclo per il foro
64 CYCL DEF 252 KREISTASCHE ~
   Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q223=+Q80  ;KREISDURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-100  ;TIEFE ~
    Q202=+10   ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206=+300  ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+1    ;EINTAUCHEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN
65 M99
66 L  Z+100 R0 FMAX ;Disimpegno
67 ;
68 ;Chiamata utensile per la sbavatura
69 TOOL CALL 170 Z S12000
70 ;
71 L  Z+100 R0 FMAX M3 ;Posizionamento ad altezza di sicurezza
72 CALL LBL 1 ;Chiamata lavorazione
73 ;
74 ;Disimpegno e fine programma
75 L  Z+100 R0 FMAX M30
76 ;
77 ;Sottoprogrammi per la lavorazione
78 LBL 1
79 FN 0: Q23 =+Q5 ;Prima profondità uguale a profondità nominale
80 FN 0: Q24 =+0 ;Contatore
81 FN 1: Q26 =+Q6 + +Q7 ;Compensazione offset fresa
82 FN 0: Q27 =+0 ;Angolo di partenza
83 FN 4: Q37 =+360 DIV +Q4 ;Passo angolare
84 CALL LBL 10 ;Chiamata dei calcoli
85 L  X+Q21  Y+Q22 FMAX ;Raggiungimento della prima posizione
86 L  Z+Q10 R0 FMAX ;Posizionamento alla distanza di sicurezza
87 L  Z-Q23 FQ11 ;Posizionarsi alla profondità di lavorazione
88 LBL 2 ;Ripetizioni
89 FN 1: Q24 =+Q24 + +1 ;Aggiornamento contatore
90 FN 1: Q27 =+Q27 + +Q37 ;Aggiornamento dell'angolo
91 CALL LBL 10 ;Chiamata dei calcoli
92 L  X+Q21  Y+Q22  Z-Q23 FQ12 ;Raggiungimento della nuova posizione
93 FN 12: IF +Q24 LT +Q4 GOTO LBL 2 ;Raggiungimento della nuova posizione
94 LBL 0
95 LBL 10 ;Calcoli
Q21 = Q26 * COS Q27 ;Nuova posizione X
Q22 = Q26 * SIN Q27 ;Nuova posizione Y
Q23 = Q3 - ( SQRT ( Q3 * Q3 - Q22 * Q22 ) ) + Q5 ;Nuova posizione Z
96 LBL 0
97 END PGM 5025_IT MM