0  BEGIN PGM 5080_IT MM 
1  ;In questo programma vengono lavorate
2  ;un'isola e una tasca rettangolari
3  ;come pure un'isola e una tasca circolari
4  ;e successivamente con un utensile
5  ;inclinato viene fresato uno smusso sui
6  ;bordi dei profili. La lavorazione dei
7  ;profili è programmata nel programma
8  ;principale, per gli smussi si richiama
9  ;un altro programma ciascuno in cui
10 ;devono essere immessi i relativi
11 ;parametri.
12 ;
13 BLK FORM 0.1 Z X+0 Y+0 Z-20
14 BLK FORM 0.2  X+200  Y+100  Z+2
15 ;Chiamata utensile
16 TOOL CALL 12 Z S6121 F4591
17 TOOL DEF 8
18 CYCL DEF 232 FRESATURA A SPIANARE ~
    Q389=+2    ;STRATEGIA ~
    Q225=+0    ;PUNTO PART. 1. ASSE ~
    Q226=+0    ;PUNTO PART. 2. ASSE ~
    Q227=+2    ;PUNTO PART. 3. ASSE ~
    Q386=+0    ;PUNTO FINALE 3. ASSE ~
    Q218=+200  ;LUNGHEZZA 1. LATO ~
    Q219=+100  ;LUNGHEZZA 2. LATO ~
    Q202=+5    ;PROF. AVANZ. MAX. ~
    Q369=+0    ;PROFONDITA' CONSEN. ~
    Q370=+1    ;SOVRAPPOSIZIONE MAX. ~
    Q207= AUTO ;AVANZAM. FRESATURA ~
    Q385= AUTO ;AVANZAMENTO FINITURA ~
    Q253= MAX ;AVANZ. AVVICINAMENTO ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q357=+2    ;DIST. SICUR LATERALE ~
    Q204=+50   ;2. DIST. SICUREZZA
19 CYCL CALL M3
20 ;
21 ;Chiamata utensile
22 TOOL CALL 8 Z S9549 F2578
23 ;Fresatura profilo esterno con ciclo SL
24 CYCL DEF 14.0 PROFILO
25 CYCL DEF 14.1 LABEL PROFILO1 /2 /3
26 CYCL DEF 20 DATI DEL PROFILO ~
    Q1=-15   ;PROFONDITA'FRESATURA ~
    Q2=+1    ;SOVRAPP.TRAIET.UT. ~
    Q3=+0    ;QUOTA LATERALE CONS. ~
    Q4=+0    ;PROFONDITA' CONSEN. ~
    Q5=+0    ;COORD. SUPERFICIE ~
    Q6=+2    ;DISTANZA SICUREZZA ~
    Q7=+50   ;ALTEZZA DI SICUREZZA ~
    Q8=+0    ;RAGGIO DELLO SMUSSO ~
    Q9=+1    ;SENSO DI ROTAZIONE
27 CYCL DEF 22 SVUOTAMENTO ~
    Q10=-7.5  ;PROF. INCREMENTO ~
    Q11= AUTO ;AVANZ. INCREMENTO ~
    Q12= AUTO ;AVANZ. PER SVUOT. ~
    Q18=+0    ;UTENSILE SGROSSATURA ~
    Q19=+2063 ;AVANZAMENTO PENDOL. ~
    Q208=+99999 ;AVANZAM. RITORNO
28 CYCL CALL M3
29 ;
30 ;Fresatura tasche
31 CYCL DEF 251 TASCA RETTANGOLARE ~
    Q215=+0    ;TIPO LAVORAZIONE ~
    Q218=+50   ;LUNGHEZZA 1. LATO ~
    Q219=+40   ;LUNGHEZZA 2. LATO ~
    Q220=+10   ;RAGGIO DELL'ANGOLO ~
    Q368=+0    ;QUOTA LATERALE CONS. ~
    Q224=+0    ;ANGOLO DI ROTAZIONE ~
    Q367=+0    ;POSIZIONE TASCA ~
    Q207= AUTO ;AVANZAM. FRESATURA ~
    Q351=+1    ;MODO FRESATURA ~
    Q201=-15   ;PROFONDITA ~
    Q202=+8    ;PROF. INCREMENTO ~
    Q369=+0    ;PROFONDITA' CONSEN. ~
    Q206=+2063 ;AVANZ. INCREMENTO ~
    Q338=+0    ;INCREMENTO FINITURA ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA ~
    Q370=+1    ;SOVRAPP.TRAIET.UT. ~
    Q366=+1    ;PENETRAZIONE ~
    Q385=+500  ;AVANZAMENTO FINITURA
32 L  X+150  Y+50 R0 FMAX M3 M99
33 ;
34 CYCL DEF 252 TASCA CIRCOLARE ~
    Q215=+0    ;TIPO LAVORAZIONE ~
    Q223=+50   ;DIAMETRO CERCHIO ~
    Q368=+0    ;QUOTA LATERALE CONS. ~
    Q207= AUTO ;AVANZAM. FRESATURA ~
    Q351=+1    ;MODO FRESATURA ~
    Q201=-15   ;PROFONDITA ~
    Q202=+8    ;PROF. INCREMENTO ~
    Q369=+0    ;PROFONDITA' CONSEN. ~
    Q206=+2063 ;AVANZ. INCREMENTO ~
    Q338=+0    ;INCREMENTO FINITURA ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA ~
    Q370=+1    ;SOVRAPP.TRAIET.UT. ~
    Q366=+1    ;PENETRAZIONE ~
    Q385=+500  ;AVANZAMENTO FINITURA
35 L  X+50  Y+50 R0 FMAX M3 M99
36 ;
37 TOOL CALL 8 Z S9549 F2500
38 M3
39 ;Spostamento origine al centro cerchio
40 CYCL DEF 7.0 PUNTO ZERO
41 CYCL DEF 7.1  X+50
42 CYCL DEF 7.2  Y+50
43 ;Chiamata programma smussi cerchio
44 CALL PGM 50801_it.h
45 ;Spostamento origine al centro rettangolo
46 CYCL DEF 7.0 PUNTO ZERO
47 CYCL DEF 7.1  X+150
48 CYCL DEF 7.2  Y+50
49 ;Chiamata programma smusso rettangolo
50 CALL PGM 50802_it.h
51 CYCL DEF 7.0 PUNTO ZERO
52 CYCL DEF 7.1  X+0
53 CYCL DEF 7.2  Y+0
54 CYCL DEF 7.3  Z+0
55 ;
56 M30 ;Fine programma
57 ;Sottoprogrammi
58 ;Profilo esterno
59 LBL 1
60 L  X-20  Y-20 RL
61 L  X+220
62 L  Y+120
63 L  X-20
64 L  Y-20
65 LBL 0
66 ;Profilo isola circolare
67 LBL 2
68 CC  X+50  Y+50
69 LP  PR+35  PA+0 RL
70 CP IPA-360 DR-
71 LBL 0
72 ;Profilo isola rettangolare
73 LBL 3
74 CC  X+150  Y+50
75 LP  PR+35  PA+0 RL
76 L  Y+20
77 RND R15
78 L IX-70
79 RND R15
80 L  Y+80
81 RND R15
82 L IX+70
83 RND R15
84 L  Y+50
85 LBL 0
86 END PGM 5080_IT MM