0  BEGIN PGM 5085_IT MM 
1  ;In questo programma vengono lavorate su un
2  ;piano ruotato un'isola e una tasca circolari
3  ;e successivamente con un utensile inclinato
4  ;viene fresato uno smusso sul perimetro dei
5  ;profili. I profili si programmano con cicli.
6  ;Per gli smussi è necessario definire i
7  ;parametri sulla base dei quali il controllo
8  ;numerico calcola le traiettorie utensile.
9  ;
10 BLK FORM 0.1 Z X-50 Y-50 Z-40
11 BLK FORM 0.2  X+50  Y+50  Z+10
12 TOOL CALL 8 Z S12000 F5000 ;Fresa D16
13 ;Rotazione piano di lavoro
14 PLANE SPATIAL SPA+10 SPB+0 SPC+0 TURN MB100 FMAX
15 CYCL DEF 232 FRESATURA A SPIANARE ~
    Q389=+1    ;STRATEGIA ~
    Q225=-50   ;PUNTO PART. 1. ASSE ~
    Q226=-60   ;PUNTO PART. 2. ASSE ~
    Q227=+20   ;PUNTO PART. 3. ASSE ~
    Q386=+0    ;PUNTO FINALE 3. ASSE ~
    Q218=+100  ;LUNGHEZZA 1. LATO ~
    Q219=+120  ;LUNGHEZZA 2. LATO ~
    Q202=+20   ;PROF. AVANZ. MAX. ~
    Q369=+0    ;PROFONDITA' CONSEN. ~
    Q370=+1    ;SOVRAPPOSIZIONE MAX. ~
    Q207= AUTO ;AVANZAM. FRESATURA ~
    Q385= AUTO ;AVANZAMENTO FINITURA ~
    Q253= MAX ;AVANZ. AVVICINAMENTO ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q357=+2    ;DIST. SICUR LATERALE ~
    Q204=+50   ;2. DIST. SICUREZZA
16 M3 M99
17 CYCL DEF 252 TASCA CIRCOLARE ~
    Q215=+0    ;TIPO LAVORAZIONE ~
    Q223=+60   ;DIAMETRO CERCHIO ~
    Q368=+0    ;QUOTA LATERALE CONS. ~
    Q207=+500  ;AVANZAM. FRESATURA ~
    Q351=+1    ;MODO FRESATURA ~
    Q201=-10   ;PROFONDITA ~
    Q202=+10   ;PROF. INCREMENTO ~
    Q369=+0    ;PROFONDITA' CONSEN. ~
    Q206=+150  ;AVANZ. INCREMENTO ~
    Q338=+0    ;INCREMENTO FINITURA ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA ~
    Q370=+1    ;SOVRAPP.TRAIET.UT. ~
    Q366=+1    ;PENETRAZIONE ~
    Q385=+500  ;AVANZAMENTO FINITURA
18 L  X+0  Y+0 R0 FMAX M3 M99
19 CYCL DEF 257 ISOLA CIRCOLARE ~
    Q223=+100  ;DIAMETRO PRECISO ~
    Q222=+142  ;DIAMETRO GREZZO ~
    Q368=+0    ;QUOTA LATERALE CONS. ~
    Q207=+500  ;AVANZAM. FRESATURA ~
    Q351=+1    ;MODO FRESATURA ~
    Q201=-10   ;PROFONDITA ~
    Q202=+10   ;PROF. INCREMENTO ~
    Q206=+3000 ;AVANZ. INCREMENTO ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA ~
    Q370=+1    ;SOVRAPP.TRAIET.UT. ~
    Q376=-1    ;ANGOLO DI PARTENZA
20 L  X+0  Y+0 R0 FMAX M3 M99
21 ;
22 ;Parametri smusso
23 Q1 = 5 ;LUNGHEZZA SMUSSO
24 Q2 = 45 ;ANGOLO SMUSSO
25 Q3 = 100 ;DIAMETRO CERCHIO
26 Q4 = 1 ;LAVORAZIONE: 1=ESTERNA 2=INTERNA
27 TOOL CALL  DL-0.5 ;Extracorsa per ottenere bordo inferiore pulito dello smusso
28 CALL LBL "fase"
29 PLANE SPATIAL SPA+10 SPB+0 SPC+0 TURN MB100 FMAX
30 ;
31 ;Parametri smusso
32 Q1 = 5 ;LUNGHEZZA SMUSSO
33 Q2 = 45 ;ANGOLO SMUSSO
34 Q3 = 60 ;DIAMETRO CERCHIO
35 Q4 = 2 ;LAVORAZIONE: 1=ESTERNA 2=INTERNA
36 TOOL CALL  DL-0.5 ;Extracorsa per ottenere bordo inferiore pulito dello smusso
37 CALL LBL "fase"
38 ;
39 M2
40 LBL "fase"
41 ;Richiesta se esterna o interna
42 FN 9: IF +Q4 EQU +2 GOTO LBL "inside"
43 FN 9: IF +Q4 EQU +1 GOTO LBL "outside"
44 STOP
45 ;Selezione per Q4 se esterna o interna
46 ;
47 LBL "inside"
48 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
49 Q10 = Q108 * ( COS Q2 ) ;Calcolo raggio compensazione utensile
50 Q11 = ( Q3 / 2 ) - Q10 ;Diametro - raggio compensazione utensile
51 Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Compensazione utensile Z
52 QL11 = Q11 - Q108 ;Posizione avvicinamento Y
53 QL12 = Q12 - 2 ;Posizione avvicinamento Z
54 L  X-Q108  Y-QL11  Z+50 R0 FMAX
55 L  A+Q2  B+0  C+0 R0 FMAX ;Importante: tutti i tre assi circolari per TCPM ... AXIS SPAT
56 L  Z-QL12 R0 F AUTO
57 CC  X+0  Y-QL11
58 CP  PA-90  Z-Q12 DR+
59 QL1 = 270
60 LBL 1
61 QL1 = QL1 + 1
62 QL2 = Q11 * COS QL1
63 QL3 = Q11 * SIN QL1
64 L  X+QL2  Y+QL3 IC+1
65 CALL LBL 1 REP359
66 CC  X+0  Y-QL11
67 CP  PA+0  Z-QL12 DR+
68 M140 MB+20
69 FN 9: IF +0 EQU +0 GOTO LBL "reset"
70 ;
71 LBL "outside"
72 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
73 Q10 = Q108 * ( COS Q2 ) ;Calcolo raggio compensazione utensile
74 Q11 = ( Q3 / 2 ) + Q10 ;Diametro + raggio compensazione utensile
75 Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Compensazione utensile Z
76 QL11 = Q11 + Q108 ;Posizione avvicinamento Y
77 QL12 = Q12 - 2 ;Posizione avvicinamento Z
78 L  X+Q108  Y-QL11  Z+50 R0 FMAX
79 L  A-Q2  B+0  C+0 R0 FMAX ;Importante: tutti i tre assi circolari per TCPM ... AXIS SPAT
80 L  Z-QL12 R0 F AUTO
81 CC  X+0  Y-QL11
82 CP IPA+90  Z-Q12 DR+
83 QL1 = 270
84 LBL 2
85 QL1 = QL1 - 1
86 QL2 = Q11 * COS QL1
87 QL3 = Q11 * SIN QL1
88 L  X+QL2  Y+QL3 IC-1
89 CALL LBL 2 REP359
90 CC  X+0  Y-QL11
91 CP  PA+180  Z-QL12 DR+
92 M140 MB+20
93 ;
94 LBL "reset"
95 FUNCTION RESET TCPM
96 L  Z+500 R0 FMAX M91
97 L  X+800  Y+600 R0 FMAX M91
98 PLANE RESET TURN FMAX
99 LBL 0
100 END PGM 5085_IT MM