0  BEGIN PGM 51001_IT MM 
1  ;Programma per creare un foro in posizione
2  ;inclinata nel pezzo.
3  ;
4  ;Chiamata utensile
5  TOOL CALL 7 Z S4000 F300
6  ;
7  L  Z+100 R0 FMAX M3 ;Posizionamento ad altezza di sicurezza
8  L  X+Q7  Y+Q8 R0 FMAX ;Preposizionamento
9  ;Spostamento origine al centro del foro.
10 ;Spostamento Z sulla posizione del quale
11 ;viene ruotato il piano di lavoro.
12 CYCL DEF 7.0 PUNTO ZERO
13 CYCL DEF 7.1  Z+Q9
14 CYCL DEF 7.2  X+Q7
15 CYCL DEF 7.3  Y+Q8
16 ;Rotazione piano di lavoro
17 CYCL DEF 19.0 PIANO DI LAVORO
18 CYCL DEF 19.1  A+Q11  B+0  C+0
19 ;Posizionamento assi rotativi
20 L  A+Q120  B+Q121  C+Q122 R0 FMAX
21 CYCL DEF 252 TASCA CIRCOLARE ~
    Q215=+0    ;TIPO LAVORAZIONE ~
    Q223=+42   ;DIAMETRO CERCHIO ~
    Q368=+0    ;QUOTA LATERALE CONS. ~
    Q207=+600  ;AVANZAM. FRESATURA ~
    Q351=+1    ;MODO FRESATURA ~
    Q201=-80   ;PROFONDITA ~
    Q202=+5    ;PROF. INCREMENTO ~
    Q369=+0    ;PROFONDITA' CONSEN. ~
    Q206=+300  ;AVANZ. INCREMENTO ~
    Q338=+0    ;INCREMENTO FINITURA ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q203=+25   ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA ~
    Q370=+1    ;SOVRAPP.TRAIET.UT. ~
    Q366=+1    ;PENETRAZIONE ~
    Q385=+500  ;AVANZAMENTO FINITURA
22 L  X+0  Y+0 R0 FMAX
23 M99
24 M140 MB MAX F9999 ;Disimpegno
25 ;Annullamento rotazione piano di lavoro
26 CYCL DEF 19.0 PIANO DI LAVORO
27 CYCL DEF 19.1  A+0  B+0  C+0
28 CYCL DEF 19.0 PIANO DI LAVORO
29 CYCL DEF 19.1
30 ;Azzeramento assi rotativi
31 L  A+Q120  B+Q121  C+Q122 R0 FMAX
32 ;Annullamento spostamento origine
33 CYCL DEF 7.0 PUNTO ZERO
34 CYCL DEF 7.1  X+0
35 CYCL DEF 7.2  Y+0
36 CYCL DEF 7.3  Z+0
37 END PGM 51001_IT MM