0  BEGIN PGM 8090_it MM 
1  ;Programma per rilevare punti di coordinate.
2  ;
3  BLK FORM 0.1 Z  X+0  Y+0  Z-20
4  BLK FORM 0.2  X+100  Y+100  Z+0
5  ;
6  ;Scrittura di BeginPGM nel protocollo
7  FN 16: F-PRINT TNC:\Database\BeginPGM.A / surface_data.txt
8  ;
9  ;Chiamata utensile tastatore
10 TOOL CALL 501 Z
11 ;
12 ;Preposizionamento
13 FN 0: Q1 =+0 ;COORDINATA DI PARTENZA IN X PER PREPOSIZIONAMENTO
14 FN 0: Q2 =+0.5 ;COORDINATA DI PARTENZA IN Y
15 LBL 1
16 FN 1: Q1 =+Q1 + +5 ;Nuovo valore in X=valore corrente+incremento
17 TCH PROBE 0.0 PIANO DI RIF Q3 Z-
18 TCH PROBE 0.1  X+Q1  Y+Q2  Z+5
19 ;
20 ;Scrittura dei valori nel protocollo
21 FN 16: F-PRINT TNC:\Database\measure.A / surface_data.txt
22 CALL LBL 1 REP18 ;18 ripetizioni, ultima coordinata X+95
23 FN 1: Q2 =+Q2 + +1 ;Incremento in Y
24 LBL 2
25 TCH PROBE 0.0 PIANO DI RIF Q3 Z-
26 TCH PROBE 0.1  X+Q1  Y+Q2  Z+5
27 ;
28 ;Scrittura dei valori nel protocollo
29 FN 16: F-PRINT TNC:\Database\measure.A / surface_data.txt
30 FN 2: Q1 =+Q1 - +5 ;Incremento in X
31 CALL LBL 2 REP18 ;18 ripetizioni, ultima coordinata X+5
32 FN 1: Q2 =+Q2 + +1 ;Incremento in Y
33 CALL LBL 1 REP49 ;49 ripetizioni, ultima fila Y+99,5
34 ;
35 ;Scrittura di EndPGM nel protocollo
36 FN 16: F-PRINT TNC:\Database\ENDPGM.A / surface_data.txt
37 ;
38 ;Fine programma
39 L  Z+100 R0 FMAX M30
40 END PGM 8090_it MM