0  BEGIN PGM 8125-it MM 
1  ;Contapezzi
2  ;In questo programma viene salvato il numero dei
3  ;pezzi forniti un una tabella affinch i valori
4  ;vengano mantenuti anche in seguito allo
5  ;spegnimento.
6  ;All'avvio del programma  necessario inserire
7  ;il valore 1 nella tabella riga 0 / colonna Q1.
8  ;All'inizio del programma si inserisce il numero
9  ;di ripetizioni desiderate. Una volta avviato
10 ;il programma, sullo schermo viene visualizzato
11 ;il numero di esecuzioni effettuate fino al
12 ;quel momento.
13 ;Una volta raggiunto il numero di ripetizioni
14 ;programmate, viene visualizzato anche questo
15 ;sullo schermo e infine il valore nella
16 ;tabella viene resettato a 1.
17 ;
18 ;
19 ;Immissione delle ripetizioni desiderate
20 Q10 = 8 ;NUMERO DI RIPETIZIONI
21 ;
22 ;Apertura della tabella
23 FN 26: TABOPEN TNC:\Database\81251-it.tab
24 ;Lettura valore corrente dalla tabella
25 FN 28: TABREAD Q1 =0 /"Q1"
26 ;
27 FN 0: Q2 =+Q1 ;Copia del valore
28 Q5 = Q1 - 1 ;Calcolo del numero attuale
29 ;
30 ;Visualizzazione del numero di ripetizioni attuali
31 FN 16: F-PRINT TNC:\Database\81252-it.a / Screen:
32 ;
33 Q1 = Q1 + 1 ;Ripresa contatore
34 ;
35 ;
36 ;Esecuzione della lavorazione desiderata.
37 ;Possibile con PGM CALL, il programma
38 ;chiamato non pu quindi contenere
39 ;alcuna funzione M2 o M30
40 CALL PGM TNC:\Database\81254-it.h
41 STOP
42 ;
43 ;
44 ;Confronto se il numero di ripetizioni
45 ; stato raggiunto
46 FN 12: IF +Q2 LT +Q10 GOTO LBL 99
47 ;Visualizzazione che il numero di ripetizioni
48 ; stato raggiunto
49 FN 16: F-PRINT TNC:\Database\81253-it.a / Screen:
50 ;
51 Q1 = 1 ;Reset contatore
52 ;Scrittura del valore del contatore nella tabella
53 FN 27: TABWRITE 0 /"Q1" = Q1
54 ;Fine programma
55 STOP
56 M30
57 ;
58 ;Label di salto se sono necessarie
59 ;ulteriori ripetizioni
60 LBL 99
61 ;Scrittura del valore del contatore nella tabella
62 FN 27: TABWRITE 0 /"Q1" = Q1
63 ;Fine programma
64 M30
65 END PGM 8125-it MM