0  BEGIN PGM 82251_IT MM 
1  ;Programma NC per proseguire il funzionamento
2  ;del contatore che legge l'orario corrente e
3  ;lo confronta con quello definito dall'operatore
4  ;nel programma 8220_it.h.
5  ;Se è stato raggiunto o superato l'orario definito
6  ;dall'operatore, il controllo numerico azzera
7  ;automaticamente il contatore.
8  ;
9  ;Incremento di uno del valore del contatore
10 QR1 = QR1 + 1
11 ;
12 ;Lettura dell'orario corrente e salvataggio in QS1
13 QS1 = SYSSTR( ID321 NR13 )
14 ;
15 ;Separazione delle ore da QS1 e salvataggio in QS20
16 QS20 = SUBSTR( SRC_QS1 BEG0 LEN2 )
17 ;
18 ;Separazione dei minuti da QS1 e salvataggio in QS21
19 QS21 = SUBSTR( SRC_QS1 BEG3 LEN2 )
20 ;
21 ;Conversione in numero della stringa in QS20 e salvataggio in QL20 (ore)
22 QL20 = TONUMB( SRC_QS20 )
23 ;
24 ;Conversione in numero della stringa in QS21 e salvataggio in QL21 (minuti)
25 QL21 = TONUMB( SRC_QS21 )
26 ;
27 ;Verifica del raggiungimento delle ore per reset
28 FN 11: IF +QL20 GT +QR10 GOTO LBL "RESET"
29 FN 12: IF +QL20 LT +QR10 GOTO LBL "NOT_RESET"
30 ;
31 ;Verifica del raggiungimento dei minuti per reset
32 FN 12: IF +QL21 LT +QR11 GOTO LBL "NOT_RESET"
33 ;
34 ;Reset contatore
35 QR1 = 0
36 ;
37 STOP
38 LBL "NOT_RESET"
39 END PGM 82251_IT MM