0  BEGIN PGM 8230_IT MM 
1  ;Programma NC per misurare nelle posizioni
2  ;di lavorazione definite in una tabella
3  ;di punti la coordinata Z esatta e inserirla
4  ;nella tabella. Di seguito è definita la
5  ;tabella di punti come modello e il controllo
6  ;numerico esegue un ciclo di lavorazione
7  ;definito nelle posizioni.
8  ;La coordinata Z inserita nella tabella
9  ;definisce il punto di partenza del ciclo in
10 ;modo tale che la profondità definita nel
11 ;ciclo si riferisca sempre alla
12 ;coordinata Z misurata in precedenza.
13 ;
14 BLK FORM 0.1 Z X-25 Y-25 Z-50
15 BLK FORM 0.2  X+25  Y+25  Z+0
16 ;
17 ;Misurazione
18 ;Chiamata utensile sistema di tastatura
19 TOOL CALL "TOUCH_PROBE" Z
20 ;
21 ;Apertura della tabella
22 FN 26: TABOPEN 82301_it.PNT
23 ;
24 Q52 = 5 ;NUMERO DI POSIZIONI DA MISURARE
25 CALL LBL "MEASURE" ;Chiamata sottoprogramma Misurazione
26 ;
27 ;Lavorazione
28 ;Chiamata utensile punta
29 TOOL CALL "DRILL_D8.5" Z S9000 F2500
30 M3
31 CYCL DEF 200 FORATURA ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q201=-2    ;PROFONDITA ~
    Q206= AUTO ;AVANZ. INCREMENTO ~
    Q202=+5    ;PROF. INCREMENTO ~
    Q210=+0    ;TEMPO ATTESA SOPRA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA ~
    Q211=+0    ;TEMPO ATTESA SOTTO ~
    Q395=+1    ;RIFERIM. PROFONDITA'
32 SEL PATTERN "82301_it.PNT"
33 L  X+0  Y+0  Z+50 R0 FMAX
34 CYCL CALL PAT FMAX
35 ;
36 CALL LBL "SAFE" ;Raggiungimento posizione di sicurezza
37 ;
38 ;Fine programma
39 M30
40 ;
41 ;Sottoprogrammi
42 ;Raggiungimento posizione di sicurezza
43 LBL "SAFE"
44 M140 MB MAX F9999
45 L  X+0  Y+0 R0 FMAX M91
46 LBL 0
47 ;
48 ;Sottoprogramma Misurazione
49 LBL "MEASURE"
50 Q50 = 0 ;Prima riga
51 Q51 = Q52 - 1 ;Calcolo del numero di ripetizioni
52 LBL "LOOP"
53 ;Lettura delle coordinate XY per misurazione
54 FN 28: TABREAD Q55 =Q50 /"X,Y"
55 TCH PROBE 427 MISURAZ. COORDINATA ~
    Q263=+Q55  ;1. PUNTO 1. ASSE ~
    Q264=+Q56  ;1. PUNTO 2. ASSE ~
    Q261=+0    ;ALTEZZA MISURATA ~
    Q320=+5    ;DISTANZA SICUREZZA ~
    Q272=+3    ;ASSE MISURATO ~
    Q267=-1    ;DIREZIONE ATTRAVERS. ~
    Q260=+15   ;ALTEZZA DI SICUREZZA ~
    Q281=+0    ;PROTOCOLLO DI MIS. ~
    Q288=+0    ;LIMITE MASSIMO ~
    Q289=+0    ;LIMITE MINIMO ~
    Q309=+0    ;STOP PGM SE ERRORE ~
    Q330=+0    ;UTENSILE ~
    Q498=+0    ;INVERSIONE UTENSILE ~
    Q531=+0    ;ANGOLO DI INCLINAZ.
56 ;Salvataggio del risultato di misura in Z nella file di punti
57 FN 27: TABWRITE Q50 /"Z" = Q160
58 Q50 = Q50 + 1 ;Incremento del numero di riga
59 CALL LBL "LOOP" REPQ51
60 LBL 0
61 END PGM 8230_IT MM