0  BEGIN PGM 8235_IT MM 
1  ;Programma NC per misurare nelle posizioni
2  ;di lavorazione definite in una tabella di
3  ;punti la coordinata Z esatta e inserirla
4  ;nella tabella.
5  ;In questo programma esemplificativo il
6  ;controllo numerico esegue la routine di
7  ;misura su cinque superfici di un dado.
8  ;Di seguito è definita per ogni lato la
9  ;relativa tabella di punti come modello e
10 ;il controllo numerico esegue un ciclo di
11 ;lavorazione definito nelle posizioni.
12 ;La coordinata Z inserita nella tabella
13 ;definisce il punto di partenza del ciclo
14 ;in modo tale che la profondità definita
15 ;nel ciclo si riferisca sempre alla
16 ;coordinata Z misurata in precedenza.
17 ;
18 BLK FORM 0.1 Z X-25 Y-25 Z-50
19 BLK FORM 0.2  X+25  Y+25  Z+0
20 ;
21 ;MISURAZIONE
22 ;
23 ;Chiamata utensile sistema di tastatura
24 TOOL CALL "TOUCH_PROBE" Z
25 ;
26 ;Lato 1
27 PLANE RESET STAY ;Reset rotazione
28 TRANS DATUM AXIS  X+0  Y+0  Z+0 ;Spostamento origine
29 ;Chiamata sottoprogramma per raggiungere posizione di sicurezza
30 CALL LBL "SAFE"
31 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX ;Rotazione piano di lavoro
32 ;
33 ;Apertura tabella di punti lato 1 
34 FN 26: TABOPEN 82351.PNT
35 Q52 = 1 ;NUMERO DI POSIZIONI
36 ;Chiamata sottoprogramma per misurazione
37 CALL LBL "MEASURE"
38 ;
39 ;Lato 2
40 PLANE RESET STAY ;Reset rotazione
41 TRANS DATUM AXIS  X+25  Y-14.1421  Z-10.8579 ;Spostamento origine
42 ;Chiamata sottoprogramma per raggiungere posizione di sicurezza
43 CALL LBL "SAFE"
44 PLANE SPATIAL SPA+90 SPB+0 SPC+90 TURN FMAX ;Rotazione piano di lavoro
45 ;
46 ;Apertura tabella di punti lato 2
47 FN 26: TABOPEN 82352.PNT
48 Q52 = 2 ;NUMERO DI POSIZIONI
49 ;Chiamata sottoprogramma per misurazione
50 CALL LBL "MEASURE"
51 ;
52 ;Lato 3
53 PLANE RESET STAY ;Reset rotazione
54 TRANS DATUM AXIS  X+14.1421  Y+25  Z-10.8579 ;Spostamento origine
55 ;Chiamata sottoprogramma per raggiungere posizione di sicurezza
56 CALL LBL "SAFE"
57 PLANE SPATIAL SPA+90 SPB+0 SPC-180 TURN FMAX ;Rotazione piano di lavoro
58 ;
59 ;Apertura tabella di punti lato 3
60 FN 26: TABOPEN 82353.PNT
61 Q52 = 3 ;NUMERO DI POSIZIONI
62 ;Chiamata sottoprogramma per misurazione
63 CALL LBL "MEASURE"
64 ;
65 ;Lato 4
66 PLANE RESET STAY ;Reset rotazione
67 TRANS DATUM AXIS  X-14.1421  Y-25  Z-10.8579 ;Spostamento origine
68 ;Chiamata sottoprogramma per raggiungere posizione di sicurezza
69 CALL LBL "SAFE"
70 PLANE SPATIAL SPA+90 SPB+0 SPC+0 TURN FMAX ;Rotazione piano di lavoro
71 ;
72 ;Apertura tabella di punti lato 4
73 FN 26: TABOPEN 82354.PNT
74 Q52 = 4 ;NUMERO DI POSIZIONI
75 ;Chiamata sottoprogramma per misurazione
76 CALL LBL "MEASURE"
77 ;
78 ;Lato 5
79 PLANE RESET STAY ;Reset rotazione
80 TRANS DATUM AXIS  X-25  Y+14.1421  Z-10.8579 ;Spostamento origine
81 ;Chiamata sottoprogramma per raggiungere posizione di sicurezza
82 CALL LBL "SAFE"
83 PLANE SPATIAL SPA+90 SPB+0 SPC-90 TURN FMAX ;Rotazione piano di lavoro
84 ;
85 ;Apertura tabella di punti lato 5
86 FN 26: TABOPEN 82355.PNT
87 Q52 = 5 ;NUMERO DI POSIZIONI
88 ;Chiamata sottoprogramma per misurazione
89 CALL LBL "MEASURE"
90 ;
91 ;LAVORAZIONE
92 ;
93 ;Chiamata utensile punta
94 TOOL CALL "DRILL_D8.5" Z S9000 F2500
95 M3
96 CYCL DEF 200 FORATURA ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q201=-2    ;PROFONDITA ~
    Q206= AUTO ;AVANZ. INCREMENTO ~
    Q202=+5    ;PROF. INCREMENTO ~
    Q210=+0    ;TEMPO ATTESA SOPRA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA ~
    Q211=+0    ;TEMPO ATTESA SOTTO ~
    Q395=+1    ;RIFERIM. PROFONDITA'
97 ;
98 ;Lato 1
99 PLANE RESET STAY ;Reset rotazione
100 TRANS DATUM AXIS  X+0  Y+0  Z+0 ;Spostamento origine
101 ;Chiamata sottoprogramma per raggiungere posizione di sicurezza
102 CALL LBL "SAFE"
103 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX ;Rotazione piano di lavoro
104 ;
105 ;Definizione della tabella di punti lato 1 come sagoma di punti
106 SEL PATTERN "82351.PNT"
107 ;Chiamata sottoprogramma per lavorazione
108 CALL LBL "MACHINING"
109 ;
110 ;Lato 2
111 PLANE RESET STAY ;Reset rotazione
112 TRANS DATUM AXIS  X+25  Y-14.1421  Z-10.8579 ;Spostamento origine
113 ;Chiamata sottoprogramma per raggiungere posizione di sicurezza
114 CALL LBL "SAFE"
115 PLANE SPATIAL SPA+90 SPB+0 SPC+90 TURN FMAX ;Rotazione piano di lavoro
116 ;
117 ;Definizione della tabella di punti lato 2 come sagoma di punti
118 SEL PATTERN "82352.PNT"
119 ;Chiamata sottoprogramma per lavorazione
120 CALL LBL "MACHINING"
121 ;
122 ;Lato 3
123 PLANE RESET STAY ;Reset rotazione
124 TRANS DATUM AXIS  X+14.1421  Y+25  Z-10.8579 ;Spostamento origine
125 ;Chiamata sottoprogramma per raggiungere posizione di sicurezza
126 CALL LBL "SAFE"
127 PLANE SPATIAL SPA+90 SPB+0 SPC-180 TURN FMAX ;Rotazione piano di lavoro
128 ;
129 ;Definizione della tabella di punti lato 3 come sagoma di punti
130 SEL PATTERN "82353.PNT"
131 ;Chiamata sottoprogramma per lavorazione
132 CALL LBL "MACHINING"
133 ;
134 ;Lato 4
135 PLANE RESET STAY ;Reset rotazione
136 TRANS DATUM AXIS  X-14.1421  Y-25  Z-10.8579 ;Spostamento origine
137 ;Chiamata sottoprogramma per raggiungere posizione di sicurezza
138 CALL LBL "SAFE"
139 PLANE SPATIAL SPA+90 SPB+0 SPC+0 TURN FMAX ;Rotazione piano di lavoro
140 ;
141 ;Definizione della tabella di punti lato 4 come sagoma di punti
142 SEL PATTERN "82354.PNT"
143 ;Chiamata sottoprogramma per lavorazione
144 CALL LBL "MACHINING"
145 ;
146 ;Lato 5
147 PLANE RESET STAY ;Reset rotazione
148 TRANS DATUM AXIS  X-25  Y+14.1421  Z-10.8579 ;Spostamento origine
149 ;Chiamata sottoprogramma per raggiungere posizione di sicurezza
150 CALL LBL "SAFE"
151 PLANE SPATIAL SPA+90 SPB+0 SPC-90 TURN FMAX ;Rotazione piano di lavoro
152 ;
153 ;Definizione della tabella di punti lato 5 come sagoma di punti
154 SEL PATTERN "82355.PNT"
155 ;Chiamata sottoprogramma per lavorazione
156 CALL LBL "MACHINING"
157 ;
158 ;Chiamata sottoprogramma per raggiungere posizione di sicurezza
159 CALL LBL "SAFE"
160 PLANE RESET TURN FMAX ;Reset rotazione
161 ;
162 ;Fine programma
163 M30
164 ;
165 ;Sottoprogrammi
166 ;Raggiungimento della prima posizione di sicurezza correlata alla macchina
167 LBL "SAFE"
168 M140 MB MAX F9999
169 L  Z+0 R0 FMAX M91
170 L  X+0  Y+0 R0 FMAX M91
171 LBL 0
172 ;
173 ;Misurazione
174 LBL "MEASURE"
175 Q50 = 0 ;Prima riga
176 Q51 = Q52 - 1 ;Calcolo del numero di ripetizioni
177 LBL "LOOP"
178 ;Lettura delle coordinate XY per misurazione
179 FN 28: TABREAD Q55 =Q50 /"X,Y"
180 TCH PROBE 427 MISURAZ. COORDINATA ~
    Q263=+Q55  ;1. PUNTO 1. ASSE ~
    Q264=+Q56  ;1. PUNTO 2. ASSE ~
    Q261=+0    ;ALTEZZA MISURATA ~
    Q320=+5    ;DISTANZA SICUREZZA ~
    Q272=+3    ;ASSE MISURATO ~
    Q267=-1    ;DIREZIONE ATTRAVERS. ~
    Q260=+15   ;ALTEZZA DI SICUREZZA ~
    Q281=+0    ;PROTOCOLLO DI MIS. ~
    Q288=+0    ;LIMITE MASSIMO ~
    Q289=+0    ;LIMITE MINIMO ~
    Q309=+0    ;STOP PGM SE ERRORE ~
    Q330=+0    ;UTENSILE ~
    Q498=+0    ;INVERSIONE UTENSILE ~
    Q531=+0    ;ANGOLO DI INCLINAZ.
181 ;Salvataggio del risultato di misura in Z nella file di punti
182 FN 27: TABWRITE Q50 /"Z" = Q160
183 Q50 = Q50 + 1 ;Incremento del numero di riga
184 CALL LBL "LOOP" REPQ51
185 LBL 0
186 ;
187 ;Lavorazione
188 LBL "MACHINING"
189 L  X+0  Y+0  Z+50 R0 FMAX ;Preposizionamento
190 CYCL CALL PAT FMAX ;Richiamo del ciclo nelle posizioni della tabella di punti
191 LBL 0
192 END PGM 8235_IT MM