0 BEGIN PGM 9035_it MM 
1 ;Programma NC per determinare automaticamente
2 ;il nome del file e incidere mediante ciclo
3 ;sul pezzo.
4 ;Il controllo numerico richiama un file maschera.
5 ;Scrive il percorso del file in un file di testo.
6 ;In seguito il controllo numerico richiama un
7 ;programma con cui seleziona il nome del programma
8 ;dal percorso del file. Il controllo numerico
9 ;salva il nome del file in QS1. Lo acquisisce al
10 ;ritorno in questo programma e lo utilizza nel ciclo
11 ;di scrittura 225.
12 ;Se i tre file impiegati non si trovano nella stessa
13 ;directory, č necessario adattare le indicazioni del
14 ;percorso nelle chiamate!
15 ;
16 ;!IMPORTANTE! Il programma non gira nella prova
17 ;programma, in quanto in essa non č ammessa la copia
18 ;di un file di testo in un programma NC!
19 ;
20 ;
21 BLK FORM 0.1 Z  X+0  Y+0  Z-20
22 BLK FORM 0.2  X+100  Y+100  Z+0
23 ;
24 ;Chiamata utensile per incidere
25 TOOL CALL 200 Z S6000
26 M3
27 ;
28 L  Z+100 R0 FMAX
29 ;
30 ;Scrittura del contenuto del file "mask" nel file "File".
31 ;Viene cosė inserito con sintassi il nome del programma.
32 FN 16: F-PRINT mask.a / FILE.a
33 ;
34 ;Chiamata programma per formazione della stringa di testo
35 CALL PGM 90351_it.H
36 ;
37 ;
38 ;Incisione del nome del file che si trova in QS1
39 CYCL DEF 225 INCISIONE ~
   QS500= QS1     ;TESTO INCISIONE ~
    Q513=+10   ;ALTEZZA CARATTERE ~
    Q514=+0    ;FATTORE DISTANZA ~
    Q515=+0    ;TIPO FONT ~
    Q516=+0    ;DISPOSIZIONE TESTO ~
    Q374=+0    ;ANGOLO DI ROTAZIONE ~
    Q517=+50   ;RAGGIO CERCHIO ~
    Q207=+500  ;AVANZAM. FRESATURA ~
    Q201=-0.3  ;PROFONDITA ~
    Q206=+150  ;AVANZ. INCREMENTO ~
    Q200=+2    ;DISTANZA SICUREZZA ~
    Q203=+0    ;COORD. SUPERFICIE ~
    Q204=+50   ;2. DIST. SICUREZZA
40 ;
41 ;Chiamata del ciclo al punto di partenza
42 L  X+20  Y+40 R0 FMAX M99
43 ;
44 ;Disimpegno
45 L  Z+100 R0 FMAX
46 ;
47 ;Fine programma
48 M30
49 END PGM 9035_it MM